1
    2
    3
    4
    5
    6
    7
    8
    9
   10
   11
   12
   13
   14
   15
   16
   17
   18
   19
   20
   21
   22
   23
   24
   25
   26
   27
   28
   29
   30
   31
   32
   33
   34
   35
   36
   37
   38
   39
   40
   41
   42
   43
   44
   45
   46
   47
   48
   49
   50
   51
   52
   53
   54
   55
   56
   57
   58
   59
   60
   61
   62
   63
   64
   65
   66
   67
   68
   69
   70
   71
   72
   73
   74
   75
   76
   77
   78
   79
   80
   81
   82
   83
   84
   85
   86
   87
   88
   89
   90
   91
   92
   93
   94
   95
   96
   97
   98
   99
  100
  101
  102
  103
  104
  105
  106
  107


base / allocator / partition_allocator / gn / BUILDCONFIG.gn [blame]

# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# This is the BUILDCONFIG for building partition_alloc as a standalone project.
#
# The config is based on:
# - skia:     //gn/BUILDCONFIG.gn
# - chromium: //build/config/BUILDCONFIG.gn

build_with_chromium = false
is_asan = false

# It's best to keep the names and defaults of is_foo flags consistent with:
# - Chrome
# - Skia.

declare_args() {
  is_official_build = false
  is_component_build = false
  dcheck_always_on = true
}

declare_args() {
  is_debug = !is_official_build
}

# Platform detection defaults:
if (target_os == "") {
  target_os = host_os
}
if (current_os == "") {
  current_os = target_os
}
if (target_cpu == "") {
  target_cpu = host_cpu
}
if (target_cpu == "x86_64") {
  target_cpu = "x64"
}
if (current_cpu == "") {
  current_cpu = target_cpu
}

is_android = current_os == "android"
is_chromeos = false
is_fuchsia = current_os == "fuchsia"
is_ios = current_os == "ios"
is_linux = current_os == "linux"
is_mac = current_os == "mac"
is_nacl = false
is_win = current_os == "win" || current_os == "winuwp"
is_cast_android = false
is_castos = false
is_chromeos_ash = false
is_cronet_build = false
enable_expensive_dchecks = false
dcheck_is_configurable = false
can_unwind_with_frame_pointers = false
is_posix = !is_win && !is_fuchsia
is_apple = is_mac || is_ios

# TODO(crbug.com/41481467): Consider expanding the standalone configuration for
# additional OSes.
assert(is_linux, "PartitionAlloc standalone only support Linux for now")
is_clang = true

# A component is either:
# - A static library (is_component_build=false)
# - A shared library (is_component_build=true)
template("component") {
  if (is_component_build) {
    _component_mode = "shared_library"
  } else {
    _component_mode = "static_library"
  }

  target(_component_mode, target_name) {
    forward_variables_from(invoker, "*")
  }
}

# Default configs
default_configs = [
  "//gn/partition_alloc:default",
  "//gn/partition_alloc:no_exceptions",
  "//gn/partition_alloc:no_rtti",
]

if (!is_debug) {
  default_configs += [
    "//gn/partition_alloc:optimize",
    "//gn/partition_alloc:NDEBUG",
  ]
}

# GCC-like toolchains, including Clang.
set_default_toolchain("//gn/toolchain:clang")
default_toolchain_name = "clang"

set_defaults("source_set") {
  configs = default_configs
}

set_defaults("component") {
  configs = default_configs
}