1
    2
    3
    4
    5
    6
    7
    8
    9
   10
   11
   12
   13
   14
   15
   16
   17
   18
   19
   20
   21
   22
   23
   24
   25
   26
   27
   28
   29
   30
   31
   32
   33
   34
   35
   36
   37
   38
   39
   40
   41
   42
   43
   44
   45
   46
   47
   48


content / browser / date_time_chooser / ios / date_time_chooser_ios.mm [blame]

// Copyright 2023 The Chromium Authors
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.

#import "content/browser/date_time_chooser/ios/date_time_chooser_ios.h"

#import <UIKit/UIKit.h>

#import "content/browser/date_time_chooser/ios/date_time_chooser_coordinator.h"
#import "ui/gfx/native_widget_types.h"

namespace content {

// DateTimeChooserIOS implementation
DateTimeChooserIOS::DateTimeChooserIOS(WebContents* web_contents)
    : DateTimeChooser(web_contents) {}

DateTimeChooserIOS::~DateTimeChooserIOS() = default;

void DateTimeChooserIOS::OnDialogClosed(bool success, double value) {
  if (open_date_time_response_callback_) {
    std::move(open_date_time_response_callback_).Run(success, value);
  }
  ClosePlatformDialog();
}

void DateTimeChooserIOS::OpenPlatformDialog(
    blink::mojom::DateTimeDialogValuePtr value,
    OpenDateTimeDialogCallback callback) {
  open_date_time_response_callback_ = std::move(callback);
  gfx::NativeWindow gfx_window = GetWebContents().GetTopLevelNativeWindow();
  coordinator_ = [[DateTimeChooserCoordinator alloc]
      initWithDateTimeChooser:this
                      configs:std::move(value)
           baseViewController:gfx_window.Get().rootViewController];
}

void DateTimeChooserIOS::ClosePlatformDialog() {
  coordinator_ = nil;
}

// static
void DateTimeChooser::CreateDateTimeChooser(WebContents* web_contents) {
  web_contents->SetUserData(UserDataKey(),
                            std::make_unique<DateTimeChooserIOS>(web_contents));
}

}  // namespace content